Windows Explorer Integration

📱 Desktop & mobile clients 💻 Desktop
3

Have you tried rebooting yet? Sometimes it takes a reboot, or at least restarting Windows Explorer for the shell extensions to start working. I actually made a script which can force this to update without rebooting, comes in handy sometimes.

Two files, fixShellExtensions.cmd and helper_registerDLLs.cmd. You just run fixShellExtensions.cmd and it will automatically ask for elevated privileges, then at the end you just exit out of the cmd prompt and it restarts Windows Explorer and shell extensions should now work (unless you have Dropbox installed, sometimes those sync icons don’t work).

fixShellExtensions.cmd:

@echo off

:: Register DLL files
start /wait %~dp0\helper_registerDLLs.cmd

:: Restart explorer
taskkill /f /im explorer.exe
start explorer.exe

helper_registerDLLs.cmd:

::::::::::::::::::::::::::::::::::::::::::::
:: Elevate.cmd - Version 4
:: Automatically check & get admin rights
::::::::::::::::::::::::::::::::::::::::::::
 @echo off
 CLS
 ECHO.
 ECHO =============================
 ECHO Running Admin shell
 ECHO =============================

:init
 setlocal DisableDelayedExpansion
 set cmdInvoke=1
 set winSysFolder=System32
 set "batchPath=%~0"
 for %%k in (%0) do set batchName=%%~nk
 set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"
 setlocal EnableDelayedExpansion

:checkPrivileges
  NET FILE 1>NUL 2>NUL
  if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )

:getPrivileges
  if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)
  ECHO.
  ECHO **************************************
  ECHO Invoking UAC for Privilege Escalation
  ECHO **************************************

  ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"
  ECHO args = "ELEV " >> "%vbsGetPrivileges%"
  ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"
  ECHO args = args ^& strArg ^& " "  >> "%vbsGetPrivileges%"
  ECHO Next >> "%vbsGetPrivileges%"

  if '%cmdInvoke%'=='1' goto InvokeCmd 

  ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"
  goto ExecElevation

:InvokeCmd
  ECHO args = "/c """ + "!batchPath!" + """ " + args >> "%vbsGetPrivileges%"
  ECHO UAC.ShellExecute "%SystemRoot%\%winSysFolder%\cmd.exe", args, "", "runas", 1 >> "%vbsGetPrivileges%"

:ExecElevation
 "%SystemRoot%\%winSysFolder%\WScript.exe" "%vbsGetPrivileges%" %*
 exit /B

:gotPrivileges
 setlocal & cd /d %~dp0
 if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul  &  shift /1)

 ::::::::::::::::::::::::::::
 ::START
 ::::::::::::::::::::::::::::
 REM Run shell as admin (example) - put here code as you like
 regsvr32.exe "C:\Program Files (x86)\Nextcloud\shellext\OCContextMenu_x64.dll"
 regsvr32.exe "C:\Program Files (x86)\Nextcloud\shellext\OCOverlays_x64.dll"
2 Likes